АмиБрокер. Color-Based System

Цветовая система для краткосрочной торговли основана на 10-периодных мементумах цены и объема, сочетание которых используется для назначения цвета графику объема.

Color-Based System

Цветовая система

Представленный ниже AFL код содержит:

  • Индикатор для визуализации цветового графика объема;
  • Код исследования для получения цветовой таблицы;
  • Код для тестирования системы основанной на данной методике.

Формула Color-Based System

// color chart code 
Range = 10; 
P2 = C; 
V2 = V; 
P1 = Ref( C, -Range ); 
V1 = Ref( V, -Range ); 
Color = IIf( P2 > P1 AND V2 > V1, colorGreen, 
IIf( P2 > P1 AND V2 < V1, colorBlue, 
IIf( P2 < P1 AND V2 < V1, colorOrange, 
/*else*/ colorRed ) ) ); 
Plot( Volume, "Volume", Color, styleHistogram | styleThick ); 
// color exploration code 
Filter = BarIndex() > Range; 
AddColumn( P2, "P2" ); 
AddColumn( V2, "Vol2", 1.0 ); 
AddColumn( Ref( DateTime(), -Range ), "Date P1", formatDateTime ); 
AddColumn( P1, "P1" ); 
AddColumn( V1, "Vol1", 1.0 ); 
AddColumn( 100 * (P2-P1)/P1, "Price delta%" ); 
AddColumn( 100 * (V2-V1)/V1, "Vol delta%" ); 
AddTextColumn( "", "V2 Color", 0, colorDefault, Color ); 
// system code 
SetTradeDelays( 1, 1, 1, 1 ); // realistic delays 
SetOption("ActivateStopsImmediately", True ); 
BuyPrice = Open; 
SellPrice = Open; 
Buy = Color == colorGreen OR Color == colorBlue; 
Sell = False; // only use stops for exit 
ApplyStop( stopTypeTrailing, stopModePercent, 1 );
Erenbur

Добавить комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *